流固耦合分析實例

2016-09-20 by:CAE仿真在線來源:互聯(lián)網(wǎng)

ANSYS+ FLUENT流-熱-固多場耦合工程實踐核心技術(shù)培訓

length=2 !定義體各種變量參數(shù),長寬高

width=3
height=2
/prep7
et,1,63   !選用殼模型
et,2,30   !選用FLUID30單元,用于流固耦合問題
r,1,0.01  增加實常數(shù),殼厚為0.01
mp,ex,1,2e11
mp,nuxy,1,0.3
mp,dens,1,7800  !定義殼單元的各種單元屬性
mp,dens,2,1000  !定義Acoustics材料來描述流體材料-水
mp,sonc,2,1400  !定義聲單元聲速
mp,mu,0,  !定義吸聲系數(shù)
!
block,,length,,width,,height !建立長方體
esize,0.5
mshkey,1
!
type,1 !選擇殼單元
mat,1
real,1
asel,u,loc,y,width   !選擇面
amesh,all!劃分面單元
alls !選擇所有項
!
type,2   !選擇聲單元
mat,2
vmesh,all!劃分體單元
fini

/solu
antype,2
modopt,unsym,10 !非對稱模態(tài)提取方法處理流固耦合問題
eqslv,front
mxpand,10,,,1
nsel,s,loc,x,
nsel,a,loc,x,length
nsel,r,loc,y
d,all,,,,,,ux,uy,uz,
nsel,s,loc,y,width,
d,all,pres,0  !上面幾步為定義邊界條件和約束
alls
asel,u,loc,y,width,
sfa,all,,fsi  !定義流固耦合界面
alls !選擇所有項
solv !求解
fini

/post1  !后處理
set,first
plnsol,u,sum,2,1   !顯示圖形
fini

/PREP7
!定義殼材料與性質(zhì)
!殼元素與材料
ET,1,shell63 $MP,EX,1,201E9 $MP,prxy,1,0.26 $MP,dens,1,7.85E3 $r,1,0.006
!流體元素與材料
ET,2,FLUID80 $MP,EX,2,1.5e9 $MP,DENS,2,0.84e3 $mp,visc,2,1.0e-10

!以下這個keyoption怎么用? 如過用1,就會顯示[Element 877 may not have a positive Z coordinate IF KEYOPT(2) = 1.],顯示這個錯誤代表要做什么修正嗎?所以我暫時用KEYOPT(2) = 0就可以跑。
KEYOPT,2,2,0

!建立殼關(guān)鍵點
K,1,10,0,0 $K,2,10,0,12

!建立中心線關(guān)鍵點
k,3,0,0,0 $k,4,0,0,20

!定義殼壁線
L,1,2 $L,1,3

!以關(guān)鍵點3,4為中心線旋轉(zhuǎn)360度生成殼體
AROTAT,all,,,,,,3,4,360

!劃分殼體網(wǎng)格
AATT,1,1,1 $esize,2 $mshape,0,3D $mshkey,2 $amesh,all $alls

!延伸出水位體積
VEXT,2,8,2,0,0,10,0,0,0 $vglue,all

csys,1
!劃分水位網(wǎng)格
type,2 $mat,2 $esize,2 $mshape,0,3D $mshkey,1 $vmesh,all
alls
!以上建模應該沒太大問題

!以下是耦合,我在流固界面上的網(wǎng)格是重合節(jié)點,特別是下面這兩段落我很不確定該怎么設(shè)定,感覺問題就出在這邊了!這里解決了應該就可以。要怎么改?或是用CP? 或是NUMMRG? 重點是流體和固體要一起動,通常設(shè)定不好就流體自己動,或是流體都跑到殼體外面去了,流體跟殼不應該穿越,而是一起有行為。
csys,1 !將工作平面定義為柱坐標。
nsel,s,loc,x,10
nrotate,all   !旋轉(zhuǎn)節(jié)點坐標系。
CPINTF,UX,0.0001, !將徑向約束(即X方向)加到節(jié)點上。

nsel,s,loc,z,0
nrotate,all
CPINTF,UZ,0.0001,

!邊界條件,將底部固定,并給予Z方向加速度。
NSEL,S,LOC,Z,0 $D,ALL,ALL $acel,,,9.8

fini
/solu
antype,modal
modopt,reduc,10,,
mxpand,10,

csys,1!Z上柱坐標系
!定義主自由度,由圖顯示感覺是沒問題,但我也不太確定。
Esel,s,type,,1  !選擇殼
Nsle,s,all !所有點
Nsel,u,loc,z,0  !排除邊界條件
m,all,ux   !(徑向)x方向的主自由度

Esel,s,type,,2  !選擇液體
Nsel,s,loc,z,10  !再選擇液面表面
m,all,uz !(豎向)z方向的主自由度

alls
solve
fini

水壩空庫
/BATCH
KEYW,PR_SET,1
KEYW,PR_STRUC,1
KEYW,PR_THERM,0
KEYW,PR_FLUID,0
KEYW,PR_ELMAG,0
KEYW,MAGNOD,0
KEYW,MAGEDG,0
KEYW,MAGHFE,0
KEYW,MAGELC,0
KEYW,PR_MULTI,0
KEYW,PR_CFD,0
/GO
!*

/prep7
!* define material proterties
mp,dens,1,2650. !mat 1 for dam
mp,ex,1,3.15e10
mp,prxy,1,.167

!* define element type
et,1,PLANE42,,,2

!* define geometry
lwater=618.
k, 1,0.0,0.0,0.0
k, 2,70.2,0.,0.
k, 3,0.,66.5,0.
k, 4,21.9875,66.5,0.
k, 5,0.,103.,0.
k, 6,14.8,103.,0.

a, 1, 2, 4, 3
a, 3, 4, 6, 5

asel,s,loc,x,0.,100.
aatt,1,,1
cm,adam,area

allsel,all

!* mesh geometry
ESIZE,0,10
lsel,s,loc,y,0.1,66.             !壩下部剖分分數(shù)
lesize,all,,,15

mshape,0,2D
mshkey,1
allsel,all
amesh,all

finish
/solu

antype,modal
MODOPT,LANB,30
MXPAND,30, , ,0

esel,s,mat,,1                      !壩體約束
nsle,s
nsel,r,loc,y,-1.0,1.0
d,all,ux,0.
d,all,uy,0.

/pbc,all,,1
/pnum,type,1
/number,1
gplot

allsel,all

save
solve

滿庫
/BATCH
KEYW,PR_SET,1
KEYW,PR_STRUC,1
KEYW,PR_THERM,0
KEYW,PR_FLUID,0
KEYW,PR_ELMAG,0
KEYW,MAGNOD,0
KEYW,MAGEDG,0
KEYW,MAGHFE,0
KEYW,MAGELC,0
KEYW,PR_MULTI,0
KEYW,PR_CFD,0
/GO
!*

/prep7
!* define material proterties
mp,dens,1,2650. !mat 1 for dam
mp,ex,1,3.15e10
mp,prxy,1,.167
mp,dens,2,1000. !mat 2 for water
mp,sonc,2,1440

!* define element type
et,1,PLANE42,,,2
et,2,29
et,3,29,,1

!* define geometry
lwater=618.
k, 1,0.0,0.0,0.0
k, 2,70.2,0.,0.
k, 3,0.,66.5,0.
k, 4,21.9875,66.5,0.
k, 5,0.,103.,0.
k, 6,14.8,103.,0.
k, 7,-1.*lwater,103.,0.
k, 8,-1.*lwater,66.5,0.
k, 9,-1.*lwater,0.,0.

a, 1, 2, 4, 3
a, 3, 4, 6, 5
a, 8, 3, 5, 7
a, 9,1, 3, 8

asel,s,loc,x,0.,100.
aatt,1,,1
cm,adam,area
asel,s,loc,x,-1*lwater,0.
aatt,2,,3
cm,awater,area

allsel,all

!* mesh geometry
ESIZE,0,10
lsel,s,loc,y,0.1,66.             !壩下部剖分分數(shù)
lesize,all,,,15
lsel,s,loc,x,-0.1,-1*lwater-1.             !水體長度方向剖分分數(shù)
lsel,r,loc,y,-0.1,67.
lesize,all,,,40,0.5
lsel,s,loc,x,-0.1,-1*lwater-1.             !水體長度方向剖分分數(shù)
lsel,r,loc,y,100.,104.
lesize,all,,,40,2.0

mshape,0,2D
mshkey,1
allsel,all
amesh,all

!更改與水體接觸的單元類型
esel,s,type,,3
nsle,s
nsel,r,loc,x,-1.,1.
esln,r
emodif,all,type,2

allsel,all

finish
/solu

antype,modal
MODOPT,UNSYM,30
MXPAND,30, , ,0

/pnum,type,1
/number,1

nsel,s,loc,x,-1.,1.             !庫水壩體FSI面
esln,s
esel,r,mat,,2
sf,all,fsi

esel,s,mat,,1                      !壩體約束
nsle,s
nsel,r,loc,y,-1.0,1.0
d,all,ux,0.
d,all,uy,0.

esel,s,mat,,2                      !水體表面約束
nsle,s
nsel,r,loc,y,102.,104.
d,all,pres,0.

/pbc,all,,1
/psf,fsi,,2

allsel,all
gplot

save
solve