建模問(wèn)題實(shí)例解析

2017-11-02 by:CAE仿真在線來(lái)源:互聯(lián)網(wǎng)

最近ANSYS建模遇到了點(diǎn)小問(wèn)題,折騰了好半天?，F(xiàn)在終于搞清楚原由了,在這里分享一下,也許能幫到大家。也方便各位童鞋朋友以后遇到類(lèi)似問(wèn)題也好有個(gè)查錯(cuò)思路。

所建模型是一個(gè)三維的線圈,處在長(zhǎng)方體空氣區(qū)域里,為后面電磁場(chǎng)分析建立幾何模型。(空氣區(qū)域需要減去線圈所占的區(qū)域)。線型結(jié)構(gòu)如下圖。

最初的建模命令如下:

/Prep7

pi=acos(-1) !定義圓周率pi

R=2 !線圈XY平面投影時(shí)中徑大小

R1=4 !線圈XZ投影是半徑大小

*do,i,0,16,1

*set,x,R*cos(i*pi/8)

*set,y,R*sin(i*pi/8)

*set,z,SQRT(R1*R1-(R*R*cos(i*pi/8)*cos(i*pi/8))) !定義XYZ坐標(biāo)點(diǎn)

k,i+1,x,y,z

*enddo

*do,i,1,9,4

bsplin,i,i+1,i+2,i+3,i+4

*enddo

KDELE,17

bsplin,13,14,15,16,1 !定義樣條曲線

kwpave,1 !將工作平面原點(diǎn)移動(dòng)到關(guān)鍵點(diǎn)1處

wpro,,90,

pcirc,0,0.1,0,360 !建立線圈截面

*do,j,1,4,1

vdrag,1+(j-1)*5,,,,,,j

*enddo !拉伸截面生成線圈實(shí)體

CM,COIL,VOLU !定義線圈組件COIL

VSEL,NONE

CSYS,0

WPAVE,0,0,0

CSYS,0

wpro,,-90, !轉(zhuǎn)換工作平面

BLOCK,-1.5*R,1.5*R,-1.5*R,1.5*R,0.5*R1,1.3*R1 !定義空氣區(qū)域

CM,AIR,VOLU

ALLSEL

VSBV,AIR,COIL,,DELE,KEEP !用線圈體減去空氣區(qū)域體

就在執(zhí)行上面這條VSBV語(yǔ)句時(shí)出現(xiàn)問(wèn)題:Topological degeneracy detected for vsbv command.try modifying geometry slightly or loosening the tolerance!

大致意思就是說(shuō):在執(zhí)行VSBV命令時(shí)檢測(cè)到了拓?fù)渫嘶?請(qǐng)嘗試稍微修改下幾何模型或者增大容差。容差放大后應(yīng)該保證在后面的操作中恢復(fù)到默認(rèn)設(shè)置。

但這個(gè)錯(cuò)誤提示感覺(jué)沒(méi)多大用處嘛。沒(méi)有具體指出來(lái)哪里出錯(cuò)了,ANSYS還是不夠智能哦。

然后就是一番百度查找問(wèn)題所在,后面經(jīng)專(zhuān)家指點(diǎn)才發(fā)現(xiàn)問(wèn)題癥結(jié)。(感謝熱情的張老師J)!放大顯示線圈后看有一個(gè)地方是下圖這樣的結(jié)構(gòu)!終于找到問(wèn)題了,就是這里建模時(shí)出現(xiàn)了間隙與干涉,導(dǎo)致后面的布爾運(yùn)算時(shí)顯示拓?fù)渫嘶奶崾?

后面的問(wèn)題當(dāng)然就是修改模型,把間隙與干涉處理掉。首先明白線圈的建模思路,先建立的16個(gè)關(guān)鍵點(diǎn)然后生成了4段樣條曲線,然后生成截面,然后拉伸截面形成線圈。分析得知這里的間隙是由于在間隙處的關(guān)鍵點(diǎn)兩邊的曲線在該點(diǎn)處的切線不共線。這里需要回到之前使用的樣條曲線命令bsplin上。查看help文檔,bsplin命令詳解如下所示。

前面6個(gè)點(diǎn)是用來(lái)指定樣條曲線經(jīng)過(guò)的點(diǎn)。注意這里可以少于6個(gè)其他幾個(gè)點(diǎn)空著就行,但不能超過(guò)6個(gè)。后面幾個(gè)參數(shù)XV1,YV1,ZV1,XV6,YV6,ZV6是用來(lái)確定點(diǎn)1和點(diǎn)6處的切線矢量的。例如XV1,YV1,ZV1=(1,1,0)就代表在1點(diǎn)處的切線是XY平面內(nèi)的45度方向。命令搞明白了,接著就修改上面的模型儂。

這里的目的就是要保證L1-L4線條在關(guān)鍵點(diǎn)1,5,9,14處切線共線。由于這四個(gè)關(guān)鍵點(diǎn)位置特殊,都為4個(gè)極點(diǎn)。所以方向矢量容易看出來(lái)。

下面是修改后的模型命令流。感興趣的朋友可以拷貝練練手。

/Prep7

pi=acos(-1)

R=2

R1=4

*do,i,0,16,1

*set,x,R*cos(i*pi/8)

*set,y,R*sin(i*pi/8)

*set,z,SQRT(R1*R1-(R*R*cos(i*pi/8)*cos(i*pi/8)))

k,i+1,x,y,z

*enddo

KDELE,17

bsplin,1,2,3,4,5,,0,-1,0,-1,0,0

bsplin,5,6,7,8,9,,1,0,0,0,-1,0

bsplin,9,10,11,12,13,,0,1,0,1,0,0

bsplin,13,14,15,16,1,,-1,0,0,0,1,0

kwpave,1

wpro,,90,

pcirc,0,0.1,0,360

*do,j,1,4,1

vdrag,1+(j-1)*5,,,,,,j

*enddo

CM,COIL,VOLU

VSEL,NONE

CSYS,0

WPAVE,0,0,0

CSYS,0

wpro,,-90,

BLOCK,-1.5*R,1.5*R,-1.5*R,1.5*R,0.5*R1,1.3*R1

CM,AIR,VOLU

ALLSEL

VSBV,AIR,COIL,,DELE,KEEP

修改后的線圈如下圖所示。這四段體相連接處都沒(méi)有間隙與干涉。VSBV布爾減操作時(shí)自然也沒(méi)有出現(xiàn)錯(cuò)誤了。

最后小結(jié)一下:以后建模時(shí)遇到這樣錯(cuò)誤提示Topological degeneracy detected for vsbv command.try modifying geometry slightly or loosening the tolerance! 建議首先將零部件放大放大在放大,看連接處有木有間隙或者干涉或者其它幾何結(jié)構(gòu)缺陷!

開(kāi)放分享：優(yōu)質(zhì)有限元技術(shù)文章,助你自學(xué)成才