基于ANSYS經(jīng)典界面的室內(nèi)聲場(chǎng)的諧響應(yīng)分析

2016-11-03  by:CAE仿真在線  來(lái)源:互聯(lián)網(wǎng)

【問(wèn)題描述】


一長(zhǎng)方體封閉空間如下圖所示,在其右上角部分有一四分之一圓柱形聲源,其振動(dòng)頻率是80hz,其最大徑向振幅是0.3048mm。在下部靠中間部分,有一窗戶?，F(xiàn)在要對(duì)該聲場(chǎng)做諧響應(yīng)分析,考察此時(shí)聲場(chǎng)的聲壓駐波云圖。

基于ANSYS經(jīng)典界面的室內(nèi)聲場(chǎng)的諧響應(yīng)分析ansys workbanch圖片1

【問(wèn)題分析】

  1. 使用FLUID30三維聲場(chǎng)單元建模該室內(nèi)聲場(chǎng)。并對(duì)室內(nèi)部分和與墻壁接觸的空氣部分分別用不同的單元建模。

  2. 使用先創(chuàng)建關(guān)鍵點(diǎn),再創(chuàng)建直線,再創(chuàng)建體的方式創(chuàng)建體,然后對(duì)體劃分網(wǎng)格。首先用耦合單元?jiǎng)澐秩矿w,然后選中中間空氣部分,修改其單元類(lèi)型為空氣單元。

  3. 對(duì)墻壁上節(jié)點(diǎn)約束所有位移。

  4. 對(duì)墻壁設(shè)置一種聲阻抗,對(duì)窗戶設(shè)置另外一種聲阻抗。

  5. 對(duì)四分之一圓柱面設(shè)置強(qiáng)制徑向位移以表達(dá)該柱面波的振幅。

  6. 設(shè)置為諧響應(yīng)分析,并設(shè)置掃頻的頻率是80HZ

  7. 后處理中分別提取聲壓的實(shí)部和虛部的駐波云圖。

  8. 使用命令流的方式進(jìn)行求解。

  9. 該例子來(lái)自于ANSYS15的聲場(chǎng)幫助中的例子(13.4. Example: Acoustic Harmonic Response in a Room),但是經(jīng)過(guò)了一些局部的調(diào)整,以更清晰的表達(dá)思路。

【求解過(guò)程】

1. 前處理

在命令窗口

基于ANSYS經(jīng)典界面的室內(nèi)聲場(chǎng)的諧響應(yīng)分析ansys workbanch圖片2

中輸入

/PREP7

以進(jìn)入前處理器。

1.1 創(chuàng)建兩種單元

在命令窗口中輸入

ET,1,30
ET,2,30,,1

其中,

第1行說(shuō)明創(chuàng)建FLUID30單元,它用于表達(dá)室內(nèi)與墻壁及振動(dòng)面接觸的部分。

第2行創(chuàng)建FLUID30單元,它用于表達(dá)室內(nèi)空氣部分。

1.2 設(shè)置材料屬性

在命令窗口中輸入

RHO=1.2041
C0=343.24
Z0=RHO*C0

其中

這3行分別用于定義三個(gè)參數(shù):空氣密度,聲音在空氣中的傳播速度,以及聲阻抗。

在命令窗口中輸入

MP,DENS,1,RHO
MP,SONC,1,C0

其中

這2行分別定義空氣的密度和聲速。

1.3 設(shè)置尺寸參數(shù),及網(wǎng)格劃分份數(shù)。

在命令窗口中輸入

LEN=8.2296
HGT=6.0960

ZL=-0.3048
RAD=0.27432

其中

這4行分別定義該封閉空間的長(zhǎng),寬,高以及振動(dòng)圓柱面的半徑。


在命令窗口中輸入

XDIV=29
YDIV=19

ZDIV=1

CDIV=2

其中

這4行分別定義該封閉空間的長(zhǎng),寬,高以及振動(dòng)圓柱面的半徑這四個(gè)方向的網(wǎng)格劃分份數(shù)。

1.4 繪制頂面幾何模型

在命令窗口中輸入

K,1
K,2,LEN
K,3,LEN,HGT
K,4,,HGT
K,5,,,ZL
K,6,LEN,,ZL
K,7,LEN,HGT,ZL
K,8,,HGT,ZL


L,1,5,1
L,2,6,1
L,3,7,1
L,4,8,1
CIRC,3,RAD,7,2,90,2

其中

前一部分用于創(chuàng)建關(guān)鍵點(diǎn),后一部分用于創(chuàng)建直線和圓。

基于ANSYS經(jīng)典界面的室內(nèi)聲場(chǎng)的諧響應(yīng)分析ansys workbanch圖片3

1.5 繪制其它幾何部分

在命令窗口中輸入

ADRAG,5,6,,,,, 3

PIO4=ATAN(1)
LENC=COS(PIO4)
LENC=LENC*RAD
HGTC=HGT-LENC
LENC=LEN-LENC

其中

第一行用于拉伸出四分之一圓柱面,下面連續(xù)5行定義了5個(gè)參數(shù)。

結(jié)果如下圖

基于ANSYS經(jīng)典界面的室內(nèi)聲場(chǎng)的諧響應(yīng)分析ansys workbanch圖片4

在命令窗口中輸入

K,15,,HGTC
K,16,,HGTC,ZL
K,17,LENC
K,18,LENC,,ZL

其中

這4行進(jìn)一步創(chuàng)建4個(gè)關(guān)鍵點(diǎn)

結(jié)果如下圖

基于ANSYS經(jīng)典界面的室內(nèi)聲場(chǎng)的諧響應(yīng)分析ansys圖片5

在命令窗口中輸入
L,1 ,17,XDIV
L,10,15,XDIV
L,11,4 ,XDIV
L,17,10,YDIV
L,15, 1,YDIV
L,2 ,9 ,YDIV
L,5 ,18,XDIV
L,13,16,XDIV
L,14,8 ,XDIV
L,18,13,YDIV
L,16,5 ,YDIV
L,6 ,12,YDIV

其中

這些行進(jìn)一步創(chuàng)建一些直線

結(jié)果如下圖

基于ANSYS經(jīng)典界面的室內(nèi)聲場(chǎng)的諧響應(yīng)分析ansys圖片6

1.6 繪制幾何體

在命令窗口中輸入

V,1 ,17,10,15, 5,18,13,16
V,15,10,11,4 ,16,13,14,8
V,17,2 ,9 ,10,18,6 ,12,13

其中

這3行用于創(chuàng)建三個(gè)體

基于ANSYS經(jīng)典界面的室內(nèi)聲場(chǎng)的諧響應(yīng)分析ansys圖片7

1.7 對(duì)體劃分網(wǎng)格

在命令窗口中輸入

ESIZE,,CDIV
VMESH,ALL
ALLS

其中

第1,2行設(shè)置了網(wǎng)格尺寸,并對(duì)體劃分了網(wǎng)格,此時(shí)所有的單元都是耦合單元類(lèi)型。

第3行選擇所有對(duì)象,以便后面的操作。

1.8 改變邊界上的單元類(lèi)型

在命令窗口中輸入

NSEL,S,LOC,X,0.0
NSEL,A,LOC,Y,0.0
NSEL,A,LOC,X,LEN
NSEL,A,LOC,Y,HGT


LOCAL,11,1,LEN,HGT
NSEL,A,LOC,X,RAD
ESLN


ESEL,INVE
TYPE,2
EMODIF,ALL

ALLS

其中

前面4行用于選擇壁面的節(jié)點(diǎn)

然后選擇與壁面節(jié)點(diǎn)關(guān)聯(lián)的單元

接著去掉這些邊界單元,只剩下房間內(nèi)的空氣部分

然后把空氣部分替換成為空氣單元類(lèi)型。

最后選擇所有對(duì)象

此時(shí),如果打開(kāi)單元類(lèi)型的編號(hào)控制,可以看到下述圖形。可見(jiàn),整個(gè)場(chǎng)被劃分為兩部分:邊界部分和中間部分。邊界部分是用耦合單元表示的,而中間部分是用純空氣單元表示的。

基于ANSYS經(jīng)典界面的室內(nèi)聲場(chǎng)的諧響應(yīng)分析ansys圖片8

1.10 對(duì)振動(dòng)面設(shè)置為流固耦合邊界條件

在命令窗口中輸入

NSEL,S,LOC,X,RAD
ESLN
SF,ALL,FSI

其中

第1行選擇半徑上的所有節(jié)點(diǎn)

第2行選擇與這些節(jié)點(diǎn)關(guān)聯(lián)的單元

第3行設(shè)置這些單元為耦合邊界。

1.11 設(shè)置墻壁上所有節(jié)點(diǎn)的位移是零

在命令窗口中輸入

CSYS,0
NSEL,S,LOC,X,0.0
NSEL,A,LOC,Y,0.0
NSEL,A,LOC,X,LEN
NSEL,A,LOC,Y,HGT
D,ALL,UX,,,,,UY,UZ

其中

中間4行選擇在壁面上的所有節(jié)點(diǎn)

最后1行設(shè)置這些節(jié)點(diǎn)不能發(fā)生位移

結(jié)果如下

基于ANSYS經(jīng)典界面的室內(nèi)聲場(chǎng)的諧響應(yīng)分析ansys結(jié)構(gòu)分析圖片9

1.12 設(shè)置耦合面上的徑向振動(dòng)幅值

在命令窗口中輸入

CSYS,11
NSEL,S,LOC,X,RAD
NROTAT,ALL
D,ALL,UX,.003048
D,ALL,UY,,,,,UZ

其中

這幾行用于說(shuō)明,將圓柱振動(dòng)面上的所有節(jié)點(diǎn),設(shè)置其徑向位移振幅是0.3048mm,而其它方向位移是零。

設(shè)置完畢后,該圓柱面上結(jié)果如下圖

基于ANSYS經(jīng)典界面的室內(nèi)聲場(chǎng)的諧響應(yīng)分析ansys結(jié)構(gòu)分析圖片10

1.13 設(shè)置墻壁的阻抗值

在命令窗口中輸入

ALLS
CSYS,0
NSEL,S,LOC,X,0.0
NSEL,A,LOC,X,LEN
NSEL,A,LOC,Y,0.0
NSEL,A,LOC,Y,HGT
SF,ALL,IMPD,Z0/0.04

其中

中間4行用于選擇墻壁面上所有的節(jié)點(diǎn),然后設(shè)置壁面節(jié)點(diǎn)的阻抗值是Z0/0.04

此時(shí),壁面上出現(xiàn)紅色方框如下圖。

基于ANSYS經(jīng)典界面的室內(nèi)聲場(chǎng)的諧響應(yīng)分析ansys結(jié)構(gòu)分析圖片11

1.14 設(shè)置窗戶的阻抗值

在命令窗口中輸入

HX=LENC/XDIV
NSEL,S,LOC,Y,0.0
NSEL,R,LOC,X,13*HX,17*HX
SF,ALL,IMPD,Z0/0.7 ! Window impedance
ALLS
FINISH

其中

第1-3行用于選擇底面中間地方的一些節(jié)點(diǎn)

第4行用于對(duì)這些節(jié)點(diǎn)設(shè)置特殊的阻抗。該區(qū)域表示該封閉空間的窗戶部分。

基于ANSYS經(jīng)典界面的室內(nèi)聲場(chǎng)的諧響應(yīng)分析ansys分析案例圖片12

2. 求解

在命令窗口中輸入

/SOLU
ANTYPE,HARM
HARF,80,80
SOLVE
FINISH

其中

上述幾行依次表明,要進(jìn)行諧響應(yīng)分析,設(shè)置激勵(lì)頻率是80HZ,也就是圓柱表面的激勵(lì)頻率80HZ,(前面知道,振副是0.3048mm),這樣就完整的表達(dá)了聲源特征。

3. 后處理

3.1 打印聲壓的實(shí)部

在命令窗口中輸入

/post1

SET,1,1
EPLOT
/EDGE,1
/TITLE,-ROOM ACOUSTICS- * REAL PART OF PRESSURE
PLNS,PRES

其中

上面幾行用于選擇結(jié)果集,并打印聲壓實(shí)部的駐波云圖。

結(jié)果如下

基于ANSYS經(jīng)典界面的室內(nèi)聲場(chǎng)的諧響應(yīng)分析ansys分析案例圖片13

3.1 打印聲壓的虛部

在命令窗口中輸入

SET,1,1,,1
/TITLE,-ROOM ACOUSTICS- * IMAG. PART OF PRESSURE
PLNS,PRES


開(kāi)放分享：優(yōu)質(zhì)有限元技術(shù)文章,助你自學(xué)成才

相關(guān)標(biāo)簽搜索：基于ANSYS經(jīng)典界面的室內(nèi)聲場(chǎng)的諧響應(yīng)分析 Ansys有限元培訓(xùn) Ansys workbench培訓(xùn) ansys視頻教程 ansys workbench教程 ansys APDL經(jīng)典教程 ansys資料下載 ansys技術(shù)咨詢 ansys基礎(chǔ)知識(shí) ansys代做 Fluent、CFX流體分析 HFSS電磁分析 Abaqus培訓(xùn) 

編輯
在線報(bào)名:
  • 客服在線請(qǐng)直接聯(lián)系我們的客服，您也可以通過(guò)下面的方式進(jìn)行在線報(bào)名，我們會(huì)及時(shí)給您回復(fù)電話，謝謝！
驗(yàn)證碼

全國(guó)服務(wù)熱線

1358-032-9919

廣州公司：
廣州市環(huán)市中路306號(hào)金鷹大廈3800
電話：13580329919
          135-8032-9919
培訓(xùn)QQ咨詢：點(diǎn)擊咨詢 點(diǎn)擊咨詢
項(xiàng)目QQ咨詢：點(diǎn)擊咨詢
email:kf@1cae.com